Trdingview主图常用指标代码

//@version=4
study(title="主图常用指标", shorttitle="主图常用指标",overlay=true)
flag = input(title="主图常用指标", defval="vegas", options=["vegas", "均线", "boll带"])
atr =ema(tr(true), 14)  

ma12 =input(12, minval=1, title="vegas过滤线") 
bei4 =input(4, minval=1, title="Vegas倍数") 

ma7 = input(7, minval=1, title="均线系统快线")
ma14 = input(14, minval=1, title="均线系统中线")
ma30 = input(30, minval=1, title="均线系统慢线")

boll= input(30, minval=1, title="布林带中轨")

parameter1 = flag=="vegas" ? ma12 : (flag=="均线" ? ma7:boll )
parameter2 = flag=="vegas" ? bei4 : ma14
parameter3 = flag=="均线" ? ma30:na

atrFlag = input(false,title = "真实波动率")

atrHigh= if(close> open)
    close+atr/2
else
    open+atr/2
atrLow = if(close> open)
    open-atr/2
else
    close-atr/2

atrHighPlot= atrFlag?atrHigh:na
atrLowPlot=  atrFlag?atrLow:na

fil1= if flag=="vegas"     
    ema(close,parameter1)
fast1Ema = if flag=="vegas"
    ema(close,144) 
slow1Ema = if flag=="vegas"
    ema(close,169) 
fast4Ema = if flag=="vegas"
    ema(close,parameter2*144)
slow4Ema =  if flag=="vegas"
    ema(close,parameter2*169)

fastEma =  if flag=="均线"
    ema(close,parameter1)
midEma =  if flag=="均线"
    ema(close,parameter2)
slowEma =  if flag=="均线"
    ema(close,parameter3)
    
basis = if flag=="boll带"
    sma(close, parameter1)
dev =  if flag=="boll带"
    2 * stdev(close,parameter1)//标准差
upper = if flag=="boll带"
    basis + dev
lower = if flag=="boll带"
    basis - dev

//输出Vegas隧道
plot (fil1,color = color.yellow,linewidth = 2,title = "过滤线")
plot (fast1Ema,color = color.blue,linewidth = 2,title = "快隧道快线")
plot (slow1Ema,color = color.blue,linewidth = 2,title = "快隧道慢线")
plot (fast4Ema,color = color.green,linewidth = 2,title = "慢隧道快线")
plot (slow4Ema,color = color.green,linewidth = 2,title = "慢隧道慢线")

//输出均线系统
plot(fastEma,color = color.yellow,linewidth = 2,title = "快线-7ema")
plot(midEma,color = color.red,linewidth = 2,title = "中线-14ema")
plot(slowEma,color = color.blue,linewidth = 2,title = "慢线-30ema")

//输出布林带
plot(basis, "中轨", color=#872323)
p1 = plot(upper, "上轨", color=color.teal)
p2 = plot(lower, "下轨", color=color.teal)
fill(p1, p2, title = "背景", color= color.rgb(19, 87, 87, 95))

//输出真实波动率
plot(atrHighPlot, color=color.yellow, title="atrHighPlot", linewidth=1 )
plot(atrLowPlot, color=color.yellow, title="atrLowPlot", linewidth=1 )